home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / antdesgn.arc / DIRECT.BAS < prev    next >
Encoding:
BASIC Source File  |  1980-01-01  |  2.0 KB  |  74 lines
  1. 10 REM DIRECTIVITY CALCULATION
  2. 20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
  3. 30 KEY OFF
  4. 40 CLS
  5. 50 PI=3.141593
  6. 60 DEF FNLOG10(X)=.4343*LOG(X)
  7. 70 COLOR 1,0
  8. 80 PRINT "DIRECTIVITY CALCULATION FOR AN ARBITRARY ANTENNA PATTERN"
  9. 90 COLOR 4,0
  10. 100 PRINT
  11. 110 PRINT "SPECIFY ANTENNA FIELD PATTERN AS A PRODUCT OF AN ARRAY"
  12. 120 PRINT "FACTOR AND AN ELEMENT FACTOR."
  13. 130 PRINT
  14. 140 PRINT "ARRAY FACTOR:"
  15. 150 INPUT "ENTER NUMBER OF ELEMENTS, SPACING(WVL), AND PHASING(deg)";N,D,AD
  16. 160 PRINT "ELEMENT FACTOR:"
  17. 170 PRINT "                  0-ISOTROPIC ELEMENT"
  18. 180 PRINT "                  1-SHORT DIPOLE (COLLINEAR)"
  19. 190 PRINT "                  2-SHORT DIPOLE (PARALLEL)"
  20. 200 PRINT "                  3-HALF-WAVE DIPOLE (COLLINEAR)"
  21. 210 PRINT "                  4-HALF-WAVE DIPOLE (PARALLEL)"
  22. 220 PRINT "                  5-OTHER"
  23. 230 INPUT "SELECT OPTION(0 TO 5)";EOP
  24. 240 IF EOP<0 OR EOP>5 THEN GOTO 230
  25. 250 INPUT "HOW MANY INTEGRATION POINTS"; M
  26. 260 M=2*INT(M/2)
  27. 270 F0=0
  28. 280 REM DO INTEGRATIONS
  29. 290 S=0
  30. 300 DTH=PI/M
  31. 310 DPH=PI/M
  32. 320 FOR I=1 TO M+1
  33. 330 TH=DTH*(I-1)
  34. 340 W=3+(-1)^I
  35. 350 IF I=1 OR I=M+1 THEN W=1
  36. 360 FOR J=1 TO 2*M+1
  37. 370 PH=DPH*(J-1)
  38. 380 V=3+(-1)^J
  39. 390 IF J=1 OR J=2*M+1 THEN V=1
  40. 400 GOSUB 570
  41. 410 FS=F*F
  42. 420 IF FS>F0 THEN F0=FS
  43. 430 S=S+FS*W*V*SIN(TH)
  44. 440 NEXT J
  45. 450 NEXT I
  46. 460 S=S*DPH*DTH/9
  47. 470 DR=4*PI*F0/S
  48. 480 DRDB=10*FNLOG10(DR)
  49. 490 PRINT
  50. 500 COLOR 14,0
  51. 510 PRINT USING "THE DIRECTIVITY IS ###.## OR ##.## dB";DR,DRDB
  52. 520 PRINT
  53. 530 COLOR 4,0
  54. 540 INPUT "CONTINUE(Y,N)";IS$
  55. 550 IF IS$="N" THEN GOTO 710
  56. 560 GOTO 40
  57. 570 REM COMPUTE FIELD PATTERN
  58. 580 STH=SIN(TH)
  59. 590 CTH=COS(TH)
  60. 600 EF=STH
  61. 610 IF EOP=0 THEN EF=1
  62. 620 IF (EOP=3 OR EOP=4) AND STH>.001 THEN EF=COS(.5*PI*CTH)/STH
  63. 630 REM NEXT STATEMENT IS FOR USER-DEFINED ELEMENT PATTERN
  64. 640 IF EOP=5 THEN EF=1
  65. 650 IF EOP=0 OR EOP=2 OR EOP>=4 THEN PSI=2*PI*D*STH*COS(PH)+AD*PI/180
  66. 660 IF EOP=1 OR EOP=3 THEN PSI=2*PI*D*CTH+AD*PI/180
  67. 670 AF=1
  68. 680 IF ABS(PSI)>.001 THEN AF=SIN(N*PSI/2)/(N*SIN(PSI/2))
  69. 690 F=AF*EF
  70. 700 RETURN
  71. 710 COLOR 7,0
  72. 720 KEY ON
  73. 730 END
  74.